$!-----------------------------------------------------------------'f$verify(0)
$! SSL_LDA.COM
$!
$! Manage the mounting and dismounting of the SSL0 LDA device.
$!
$! Copyright (C) 1996-2026 Mark G.Daniel.
$!
$! Licensed under the Apache License, Version 2.0 (the "License");
$! you may not use this file except in compliance with the License.
$! You may obtain a copy of the License at
$!
$!    http://www.apache.org/licenses/LICENSE-2.0
$!
$! Unless required by applicable law or agreed to in writing, software
$! distributed under the License is distributed on an "AS IS" BASIS,
$! WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
$! See the License for the specific language governing permissions and
$! limitations under the License.
$!
$! 20-DEC-2025  MGD  initial
$!-----------------------------------------------------------------------------
$!    
$ ss$_abort = 44
$ ss$_forget = 1761
$ if f$search("WASD_ROOT:[INSTALL]SSL_DETECT.COM") .nes. ""
$    then procedures = "WASD_ROOT:[INSTALL]"
$    else procedures = "[]"
$ endif
$ @'procedures'ARCHER.COM
$!    
$ ssl0_dir = "wasd_root:[src.httpd]"
$ ssl0_dir = f$parse(ssl0_dir,,,"device") +-
             f$parse(ssl0_dir,,,"directory") --
             "]" + ".obj_" + wasd_arch_name + "]"
$ if f$search("''ssl0_dir'OSSL$LIBSSL32.OLB") .eqs. "" .or. -
     f$search("''ssl0_dir'OSSL$LIBCRYPTO32.OLB") .eqs. "" .or. -
     f$search("''ssl0_dir'OSSL_INCLUDE.DSK") .eqs. ""
$ then
$    exit ss$_forget
$ endif
$!
$ p1 = f$edit(p1,"upcase")
$!
$ wasd_lda = f$trnlnm("WASD_LDA")
$ if wasd_lda .eqs. "" then wasd_lda = "LDA190:"
$ p1 = f$edit(p1,"upcase")
$!
$ if p1 .eqs. "MOUNT"
$ then
$    if .not. f$getdvi("LDA0:","exists")
$    then
$       write sys$output "*** REQUIRES LD *** (@SYS$STARTUP:LD$STARTUP)"
$       exit ss$_abort
$    endif
$    if f$getdvi(wasd_lda,"exists")
$    then
$       set noon
$       dismount 'wasd_lda'
$       set on
$       ld disconnect 'wasd_lda'
$    endif
$    ld connect 'ssl0_dir'ossl_include.dsk 'wasd_lda'
$    mount 'wasd_lda' ossl_include
$    define /job /nolog WASD_SSLROOT "SSL0$ROOT","*"
$    define /job /nolog WASD_OPENSSL "''wasd_lda'[INCLUDE.OPENSSL]"
$    define /job /nolog WASD_LIBSSL "''ssl0_dir'OSSL$LIBSSL32.OLB/LIBRARY"
$    define /job /nolog WASD_LIBCRYPTO "''ssl0_dir'OSSL$LIBCRYPTO32.OLB/LIBRARY"
$    define /job /nolog OPENSSL "''f$trnlnm("WASD_OPENSSL","LNM$JOB")'"
$    exit
$ endif
$!
$ if p1 .eqs. "DISMOUNT"
$ then
$    if f$getdvi(wasd_lda,"exists")
$    then
$       dismount 'wasd_lda'
$       ld disconnect 'wasd_lda'
$       deassign /job /nolog OPENSSL
$    endif
$    exit
$ endif
$!
$ exit ss$_abort
$!-----------------------------------------------------------------------------