$!
$! This command procedure is invoked by the SSL3 PCSI kit,
$! during the preconfiguration phase of the installation.
$! It will run after the user has chosen the product to
$! install, but before any questions are asked of the user.
$!
$!
$ if f$getsyi("STARTUP_P1") .eqs. "INST"
$ then
$!
$!      Do nothing.  SIP kit processing will take over here.
$!
$ else
$!
$!   Reset the logical name so we don't pick it up from
$!   a previous installation.
$!
$    if f$trnlnm("SSL3$USED_DEST") .nes. ""
$    then
$       deassign/system/exec SSL3$USED_DEST
$    endif
$!
$    target_device = f$parse(f$trnlnm("PCSI$DESTINATION"),,,"DEVICE","SYNTAX_ONLY")
$!
$    if f$trnlnm("PCSI$DESTINATION") .nes. "''target_device'[VMS$COMMON.]"
$    then
$!
$       write sys$output " "
$       write sys$output " As of SSL3 V3.0, installation to locations other than the system disk is"
$       write sys$output " not recommended.  The use of the /DESTINATION qualifier is also discouraged."
$       write sys$output " "
$       write sys$output " Please use the following command to install SSL3: "
$       write sys$output " "
$       write sys$output "      $ PRODUCT INSTALL SSL3"
$       write sys$output " "
$!
$!      Set the logical so that we can test inside the .PCSI$DESC
$!      file for it, and then take an appropriate action.
$!
$       define/system/exec SSL3$USED_DEST true
$!
$    endif              ! PSCI$DESTINATION is not equal to target_device:[VMS$COMMON.]
$!
$ endif                 ! f$getsyi("STARTUP_P1")
$!
$ freeblocks = f$getdvi("PCSI$DESTINATION","freeblocks")
$ IF (freeblocks .GE. 0) .AND. (freeblocks .LT. 200000)
$ THEN
$     define/system/exec SSL3$NO_SPACE true
$ ELSE
$     define/system/exec SSL3$NO_SPACE false
$ ENDIF
$ exit 1        ! SS$_NORMAL