$!
$! This command procedure is used to generate, delete,
$! backup or restore FIPS module configuration file.
$!
$!
$  IF F$GETSYI("STARTUP_P1") .EQS. "INST"
$  THEN
$!   Do nothing. SIP kit processing will take over here.
$  ELSE
$    IF P1 .EQS. "BACKUP"       THEN GOSUB BACKUP
$    IF P1 .EQS. "RESTORE"      THEN GOSUB RESTORE
$    IF P1 .EQS. "INITIALIZE"   THEN GOSUB INITIALIZE
$    IF P1 .EQS. "DEINITIALIZE" THEN GOSUB DEINITIALIZE
$  ENDIF
$  EXIT 1
$!
$!
$! Backup old FIPS module configuration files.
$  BACKUP:
$    IF F$SEARCH("PCSI$DESTINATION:[SSL3]FIPSMODULE.CNF_AUTOGEN") .NES. ""
$    THEN
$      RENAME PCSI$DESTINATION:[SSL3]FIPSMODULE.CNF_AUTOGEN;* PCSI$DESTINATION:[SSL3]FIPSMODULE.CNF_AUTOGEN_BACKUP;*
$    ENDIF
$    RETURN
$!
$! Restore old FIPS module configuration files in case of termination.
$  RESTORE:
$    IF F$SEARCH("PCSI$DESTINATION:[SSL3]FIPSMODULE.CNF_AUTOGEN_BACKUP") .NES. ""
$    THEN
$      RENAME PCSI$DESTINATION:[SSL3]FIPSMODULE.CNF_AUTOGEN_BACKUP;* PCSI$DESTINATION:[SSL3]FIPSMODULE.CNF_AUTOGEN;*
$    ENDIF
$    RETURN
$!
$! Generate FIPS module configuration file.
$  INITIALIZE:
$    MCR SSL3$EXE:OPENSSL fipsinstall -out "SSL3$ROOT:[000000]FIPSMODULE.CNF_AUTOGEN" -module SSL3$MODULES:FIPS.EXE
$    RETURN
$!
$! Delete FIPS module configuration file.
$  DEINITIALIZE:
$    IF F$SEARCH("PCSI$DESTINATION:[SSL3]FIPSMODULE.CNF_AUTOGEN") .NES. ""
$    THEN
$      DELETE PCSI$DESTINATION:[SSL3]FIPSMODULE.CNF_AUTOGEN;*
$    ENDIF
$    RETURN
$!