$!-----------------------------------------------------------------------------
$! BUILD_PROXYMUNGE.COM
$!
$! P1 == LINK or BUILD or empty (builds)
$! P2 == SSL then build for SSL
$!
$! 12-DEC-2024  MGD  tweak [INSTALL]SSL_DETECT.COM
$! 30-JUL-2020  MGD  broaden to include VSI SSL111 (what a munge!)
$! 23-FEB-2020  MGD  adapt to OpenSSL 1.1.n and later (WASD OpenSSL only)
$! 22-SEP-2007  MGD  initial
$!-----------------------------------------------------------------------------
$!
$ ss$_abort = 44
$ on controly then exit ss$_abort
$ p1 = f$edit(p1,"upcase")
$ p2 = f$edit(p2,"upcase")
$!
$ @WASD_ROOT:[INSTALL]ARCHER.COM "PROXYMUNGE"
$!
$ build_datetime = "BUILD_DATETIME=""""""""""""" +-
                   f$extract(0,10,f$cvtime()) + ":" +-
                   f$extract(11,8,f$cvtime()) + """"""""""""""
$!
$ cgilib_olb = "[src.misc.obj_''wasd_arch_name']cgilib.olb"
$
$ defines = " /define=(__VMS_VER=70000000,__CRTL_VER=70000000," +-
                       "CGILIB_OBJECT_MODULE,''BUILD_DATETIME')"
$!
$ includes = " /include=[-.misc]"
$ warnings=  " /warning=(DISABLE=(PREOPTW,IMPLICITFUNC," +-
                         "NEEDCONSTEXT,ADDRCONSTEXT,CXXPRAGMANA))"
$ cc_options = "/DECC /OPTIMIZE /STAND=RELAXED /PREFIX=ALL /NAMES=AS_IS" +-
               includes + defines + warnings
$!
$ if p2 .eqs. "SSL" .or. p2 .eqs. "SSL=0"
$ then
$    write sys$output ""
$    @wasd_root:[install]ssl_setup 'p2'
$    wasd_sslroot = f$trnlnm("WASD_SSLROOT","lnm$job")
$    if wasd_sslroot .eqs. "" .or. wasd_sslroot .eqs. "!" -
        then exit ss$_abort
$    defines = defines - ")" + ",MUNGE_VIA_SSL=1)"
$ else
$    wasd_sslroot = ""
$    defines = defines - ")" + ",MUNGE_VIA_SSL=0)"
$ endif
$!
$ if p1 .eqs. "" .or. p1 .eqs. "BUILD" .or. p1 .eqs. "COMPILE"
$ then
$    set on
$    if f$locate ("SSL0$",wasd_sslroot) .lt. f$length(wasd_sslroot) -
        then @WASD_ROOT:[INSTALL]SSL_LDA MOUNT
$    set noon
$    set verify
$    cc 'cc_options' /object='object_dir' proxymunge
$!   'f$verify(0)
$    @WASD_ROOT:[INSTALL]SSL_LDA DISMOUNT
$    set on
$ endif
$!
$ if p1 .eqs. "" .or. p1 .eqs. "BUILD" .or. p1 .eqs. "LINK"
$ then
$    if p2 .eqs. "SSL"  .or. p2 .eqs. "SSL=0"
$    then
$       link_options = "," + f$trnlnm ("WASD_SSL_OPT","lnm$job") + "/options"
$    else
$       link_options = ""
$    endif
$    set verify
$ link /notrace /executable=wasd_exe:proxymunge.exe -
  [.obj_'wasd_arch_name']geolocate,-
  'cgilib_olb'/library'link_options'
$!   'f$verify(0)
$ endif
$ purge /nolog 'object_dir'
$! 
$!-----------------------------------------------------------------------------