$!-----------------------------------------------------------------------------
$! BUILD_HTTPDMON_GEOLOCATE.COM
$!
$! P1 == LINK or BUILD or empty (builds)
$! P2 == optional SSL
$!
$! 25-JAN-2026  MGD  modify to keep the selected SSL kit in job logicals
$!                   modify to accomodate local OpenSSL OSSL_INCLUDE.DSK,
$!                     SSL$LIBSSL32.OLB and OSSL$LIBCRYPTO32.OLB libraries
$! 01-MAR-2022  MGD  initial provide for a geolocation HTTPdmon
$!-----------------------------------------------------------------------------
$!
$ ss$_abort = 44
$ on controly then exit ss$_abort
$ p1 = f$edit(p1,"upcase")
$ p2 = f$edit(p2,"upcase")
$!
$ @wasd_root:[install]archer.com "HTTPDMON (GEOLOCATE)"
$!
$ defines = " /define=(__VMS_VER=70000000,__CRTL_VER=70000000,HTTPDMON_GEOLOCATE=1,GEOLOCATE_OBJECT=1)"
$!
$!(currently GeoLocate does not use any secure services)
$ if p2 .eqs. "SSL" .or. p2 .eqs. "SSL=0"
$ then
$    write sys$output ""
$    @wasd_root:[install]ssl_setup 'p2'
$    wasd_sslroot = f$trnlnm("WASD_SSLROOT","lnm$job")
$    if wasd_sslroot .eqs. "" .or. wasd_sslroot .eqs. "!" -
        then exit ss$_abort
$    defines = defines - ")" + ",GEOLOCATE_OPENSSL)"
$ else
$    wasd_sslroot = ""
$ endif
$!
$ includes = ""
$ warnings=  " /WARNING=(NOINFORM,DISABLE=(PREOPTW))"
$ cc_options = "/DECC /OPTIMIZE /STAND=RELAXED_ANSI /PREFIX=ALL /NAMES=AS_IS" +-
               INCLUDES + DEFINES + WARNINGS
$!
$ if p1 .eqs. "" .or. p1 .eqs. "BUILD" .or. p1 .eqs. "COMPILE"
$ then
$    set on
$    if f$locate ("SSL0$",wasd_sslroot) .lt. f$length(wasd_sslroot) -
        then @WASD_ROOT:[INSTALL]SSL_LDA MOUNT
$    set noon
$    set verify
$    cc 'cc_options' /object='wasd_obj_dir'geolocate_object GEOLOCATE
$    cc 'cc_options' /object='wasd_obj_dir'httpdmon_geolocate HTTPDMON
$!   'f$verify(0)
$    @WASD_ROOT:[INSTALL]SSL_LDA DISMOUNT
$    set on
$ endif
$!
$ if p1 .eqs. "" .or. p1 .eqs. "BUILD" .or. p1 .eqs. "LINK"
$ then
$    cgilib_olb = "[src.misc.obj_''wasd_arch_name']cgilib.olb"
$    if p2 .eqs. "SSL"  .or. p2 .eqs. "SSL=0"
$    then
$       link_options = "," + f$trnlnm ("WASD_SSL_OPT","lnm$job") + "/options"
$    else
$       link_options = ""
$    endif
$    set verify
$ link /notrace /executable=wasd_exe:httpdmon_geolocate.exe -
  [.obj_'wasd_arch_name']httpdmon_geolocate,-
  [.obj_'wasd_arch_name']geolocate_object,-
  'cgilib_olb'/library'link_options'
$!   'f$verify(0)
$ endif
$ purge /nolog 'object_dir'
$!
$!-----------------------------------------------------------------------------