$!-----------------------------------------------------------------------------
$! BUILD_GEOLOCATE.COM
$!
$! P1 == LINK or BUILD or empty (builds)
$! P2 == OBJECT to build object module
$! P3 == SSL to build TLS-capable
$!
$! 25-JAN-2026  MGD  modify to keep the selected SSL kit in job logicals
$!                   modify to accomodate local OpenSSL OSSL_INCLUDE.DSK,
$!                     SSL$LIBSSL32.OLB and OSSL$LIBCRYPTO32.OLB libraries
$! 12-DEC-2024  MGD  tweak [INSTALL]SSL_DETECT.COM
$! 18-MAR-2022  MGD  initial
$!-----------------------------------------------------------------------------
$!
$ ss$_abort = 44
$ on controly then exit ss$_abort
$ on error then continue
$!
$ @WASD_ROOT:[INSTALL]ARCHER.COM "GEOLOCATE"
$!
$ p1 = f$edit(p1,"upcase")
$ p2 = f$edit(p2,"upcase")
$ p3 = f$edit(p3,"upcase")
$!
$ build_datetime = "BUILD_DATETIME=""""""""""""" +-
                   f$extract(0,10,f$cvtime()) + ":" +-
                   f$extract(11,8,f$cvtime()) + """"""""""""""
$!
$ defines = " /define=(__VMS_VER=70000000," +-
                       "__CRTL_VER=70000000,CGILIB_OBJECT_MODULE," +-
                       "''BUILD_DATETIME')"
$!
$ if p2 .eqs. "OBJECT"
$ then
$    defines = defines - ")" + ",GEOLOCATE_OBJECT)"
$    object = "_OBJECT"
$ else
$    object = ""
$ endif
$!
$!(currently GeoLocate does not use any secure services)
$ if p3 .eqs. "SSL" .or. p3 .eqs. "SSL=0"
$ then
$    write sys$output ""
$    @wasd_root:[install]ssl_setup 'p3'
$    wasd_sslroot = f$trnlnm("WASD_SSLROOT","lnm$job")
$    if wasd_sslroot .eqs. "" .or. wasd_sslroot .eqs. "!" -
        then exit ss$_abort
$    defines = defines - ")" + ",GEOLOCATE_OPENSSL)"
$ else
$    wasd_sslroot = ""
$ endif
$!
$ includes = " /include=[src.misc]"
$ warnings=  " /warning=(disable=(PREOPTW,IMPLICITFUNC," +-
                                  "NEEDCONSTEXT,ADDRCONSTEXT,CXXPRAGMANA))"
$!
$ if p1 .eqs. "" .or. p1 .eqs. "BUILD" .or. p1 .eqs. "COMPILE"
$ then
$    cc_options = "/decc /optimize /stand=relaxed /prefix=all /names=as_is" +-
                  includes + defines + warnings
$    set on
$    if f$locate ("SSL0$",wasd_sslroot) .lt. f$length(wasd_sslroot) -
        then @WASD_ROOT:[INSTALL]SSL_LDA MOUNT
$    set noon
$    set verify
$ cc 'cc_options' /object='object_dir'geolocate'object' geolocate
$!   'f$verify(0)
$    set on
$    @WASD_ROOT:[INSTALL]SSL_LDA DISMOUNT
$ endif
$!
$ if p1 .eqs. "" .or. p1 .eqs. "BUILD" .or. p1 .eqs. "LINK"
$ then
$    cgilib_olb = "[src.misc.obj_''wasd_arch_name']cgilib.olb"
$    if p3 .eqs. "SSL"  .or. p3 .eqs. "SSL=0"
$    then
$       link_options = "," + f$trnlnm ("WASD_SSL_OPT","lnm$job") + "/options"
$    else
$       link_options = ""
$    endif
$    set verify
$ link /notrace /executable=wasd_exe:geolocate.exe -
  [.obj_'wasd_arch_name']geolocate,-
  'cgilib_olb'/library'link_options'
$!   'f$verify(0)
$ endif
$ purge /nolog 'object_dir'
$! 
$!-----------------------------------------------------------------------------